#!/bin/csh

# c-shell script to calculate lag correlation

# !!!!!! What should be modified !!!!!!
# HHH  : home directory
# var  : name of data
# XXX  : number of grid in longitude
# YYY  : number of grid in latitude
# DDD  : number of days per 1 year (for models using 360 day calendar)
# TTT  : number of total time (in day)
# BYY  : first year (e.g. 1979)
# NYR  : number of years (e.g. 27 for 1979-2005)
# NYR1 : NYR - 1
# LYR  : whether the data has leap year or not
#  (e.g. 1 : leap year, 0 : no leap year)
# LNX  : whether the machine is linux or not
#  This is for the record length problem.
#  (e.g. 4 : linux machine, 1 : other machine)
# MMM  : missing value
# PPP  : period of data

# for ctl file
# BLO  : starting longitude
# BLA  : starting latitude
# DLO  : delta longitude
# DLA  : delta latitude
# !!!!!! What should be modified !!!!!!

#enver setenv HHH /jdata4/cdl/kim/msd
 setenv HHH ~/work/programs/MJOWG/msd




 foreach var ( olr_av u850_n1 u200_n1 )

 setenv DDD 365
 setenv TTT 9862
 setenv BYY 1979
 setenv LYR 1
 setenv LNX 1
 setenv MMM -999.
 setenv PPP 19790101_20051231

# for ctl file
 setenv BLO 0.0
 setenv BLA -90.0
 setenv DLO 2.5
 setenv DLA 2.5

@ NYR = 27
@ NYR1 = $NYR - 1

 cd $HHH/level_1/$var

# output directory
 mkdir -p lgc

# source directory
 mkdir -p src/lgc
 cd src/lgc

 cp -f $HHH/level_1/sample/lgc/input.nml.sample .
 cp -f $HHH/level_1/sample/lgc/llreg_2d.f90 .

 foreach exp (east.win east.sum north.io north.wp)

  if ( $exp == 'east.win' ) then
   setenv XXX 144
   setenv YYY 1
   setenv SEA 1
   setenv NYY $NYR1
   setenv REG 10S10N
   setenv FIL IO.win
  else if ( $exp == 'east.sum' ) then
   setenv XXX 144
   setenv YYY 1
   setenv SEA 2
   setenv NYY $NYR
   setenv REG 10S10N
   setenv FIL IO.sum
  else if ( $exp == 'north.io' ) then
   setenv XXX 1
   setenv YYY 73
   setenv SEA 2
   setenv NYY $NYR
   setenv REG 80E100E
   setenv FIL IO.sum
  else if ( $exp == 'north.wp' ) then
   setenv XXX 1
   setenv YYY 73
   setenv SEA 2
   setenv NYY $NYR
   setenv REG 115E135E
   setenv FIL IO.sum
  endif

 sed "s#homedir#$HHH#g"  input.nml.sample > tmp1
 sed "s/variable/$var/g"             tmp1 > tmp2
 sed "s/num_x/$XXX/g"                tmp2 > tmp1
 sed "s/num_y/$YYY/g"                tmp1 > tmp2
 sed "s/num_d/$DDD/g"                tmp2 > tmp1
 sed "s/num_t/$TTT/g"                tmp1 > tmp2
 sed "s/num_r/$NYY/g"                tmp2 > tmp1
 sed "s/beg_year/$BYY/g"             tmp1 > tmp2
 sed "s/leap_year/$LYR/g"            tmp2 > tmp1
 sed "s/linux_recl/$LNX/g"           tmp1 > tmp2
 sed "s/beg_lon/$BLO/g"              tmp2 > tmp1
 sed "s/beg_lat/$BLA/g"              tmp1 > tmp2
 sed "s/del_lon/$DLO/g"              tmp2 > tmp1
 sed "s/del_lat/$DLA/g"              tmp1 > tmp2
 sed "s/zm/$REG/g"                   tmp2 > tmp1
 sed "s/in_name/$FIL/g"              tmp1 > tmp2
 sed "s/out_name/$exp/g"             tmp2 > tmp1
 sed "s/sea_num/$SEA/g"              tmp1 > tmp2
 sed "s/missing/$MMM/g"              tmp2 > tmp1
 sed "s/period/$PPP/g"               tmp1 > input.nml

f95 -ffree-line-length-none llreg_2d.f90
a.out
rm -f a.out

 end

 end